Rang: Administration
Gruppen: Administration
Mitglied seit: 6/25/2009
Beiträge: 7
|
Mit Hilfe dieses Skripts ist es möglich ein automatisiertes Backup für den AuktionatorNET einzurichten.
Das Tool Robocopy wird benötigt. Für Windows Server 2003 und Windows XP können Sie es unter http://www.microsoft.com/Downloads/details.aspx?FamilyID=9d467a69-57ff-4ae7-96ee-b18c4790cffd&displaylang=en herunterladen. Das Tool Robocopy.exe muss nach der Installation in den System32 Ordner der Windows-Installation kopiert werden. In Windows Vista und Windows Server 2008 ist das Tool schon vorhanden und muss somit nicht heruntergeladen bzw. kopiert werden.
Das Skript ist nur für Experten geeignet. Andernfalls verwenden Sie bitte die manuelle Sicherung im Programm oder eine professionelle Backup-Software, wie z.B. Symantec Backup Exec.
Das folgende Skript kann als name.bat-Datei gespeichert werden und über den Windows-Taskplaner automatisiert werden. Variablen müssen Sie gegebenenfalls anpassen. Alle Daten im Zielpfad werden gelöscht!
Code::: --- DATENBANK ---
::--- Datenbank sichern und auf lokalen Medium zwischenspeichern ---
:: --- Variablen fuer MSSQL setzen ---
set SQLCMD="C:\Programme\Microsoft SQL Server\90\Tools\Binn\SQLCMD.EXE"
set SQL_SERVER=SERVER\MSSQLNETZONE
set DB_NAME=AuktionatorNET
set BACKUP_PFAD=C:\Programme\Microsoft SQL Server\MSSQL.1\MSSQL\Backup\AuktionatorNET_db.bak
:: --- altes Backup loeschen ---
if exist "%BACKUP_PFAD%" (del "%BACKUP_PFAD%")
:: 11 entspricht 10 Sekunden warten
ping -n 11 127.0.0.1 > NUL
:: --- Sicherung ausfuehren ---
%SQLCMD% -E -S %SQL_SERVER% -Q "BACKUP DATABASE %DB_NAME% TO DISK = '%BACKUP_PFAD%' WITH INIT, NOUNLOAD"
:: 11 entspricht 10 Sekunden warten
ping -n 11 127.0.0.1 > NUL
:: --- Datenbank auf externes Medium spiegeln ---
:: --- Variablen fuer Datenbank-Sicherung setzen ---
:: WICHTIG: KEIN BACKSLASH AM ENDE DER PFADE!!!
set QUELL_PFAD=C:\Programme\Microsoft SQL Server\MSSQL.1\MSSQL\Backup
set ZIEL_PFAD=Z:\AuktionatorNET_DB
set LOG_PFAD=C:\Programme\NetZone GmbH\Sicherung AuktionatorNET DB.log
if exist "%LOG_PFAD%" (del "%LOG_PFAD%")
echo "" >> "%LOG_PFAD%"
:: --- Sicherung ausfuehren
robocopy "%QUELL_PFAD%" "%ZIEL_PFAD%" /MIR /FFT /R:1 /W:5 /LOG:"%LOG_PFAD%" /NP /V
:: --- PROGRAMM ---
:: --- AuktionatorNET auf externes Medium spiegeln ---
:: --- Variablen fuer Programm-Sicherung setzen ---
:: WICHTIG: KEIN BACKSLASH AM ENDE DER PFADE!!!
set QUELL_PFAD=C:\Programme\NetZone GmbH\AuktionatorNET
set ZIEL_PFAD=Z:\AuktionatorNET
set LOG_PFAD=C:\Programme\NetZone GmbH\Sicherung AuktionatorNET.log
if exist "%LOG_PFAD%" (del "%LOG_PFAD%")
echo "" >> "%LOG_PFAD%"
:: --- Sicherung ausfuehren
robocopy "%QUELL_PFAD%" "%ZIEL_PFAD%" /MIR /FFT /R:1 /W:5 /LOG:"%LOG_PFAD%" /NP /V
|
